Игра ЯЙЦА

User avatar
Фант
Posts: 1363
Joined: Sat Nov 30, 2013 10:01 am
My devices: iPad 4 (iOS 9.3), iMac (MAC OS 11.03)
Location: Россия,Санкт-Петербург
Flag: Russia
Contact:

Re: Игра ЯЙЦА

Post by Фант » Wed Dec 23, 2015 1:02 pm

Обновление. Игра получила свое логическое завершение.
1. Добавлена возможность сохранения лучшего результата в игре. (В директории с файлом Яйца.txt появится папка System с файлом Best. В нем будет хранится улучшенный результат в игре.)
2. Яйца с правых насестов летят и крутятся теперь в правильном направлении.
[code]'установочные команды
GRAPHICS
'SET TOOLBAR OFF
PAGE 2 SET
PAGE 2 COLOR 1,0,0,.7
PAGE 2 HIDE
PAGE 1 SET
SET ORIENTATION LANDSCAPE
RANDOMIZE
OPTION BASE 1
OPTION ANGLE DEGREES
OPTION TEXT POS CENTRAL
OPTION SPRITE POS CENTRAL
OPTION IMAGE POS CENTRAL
SET LISTS CUSTOM
SET BUTTONS CUSTOM
OPTION SORT DESCENDING
REFRESH OFF
'создание папки с файлом для записи лучшего результата
IF FILE_EXISTS ("System")=0 THEN DIR "System" CREATE
IF FILE_EXISTS ("System/Best")=0 THEN FILE "System/Best" PRINT 0
FILE "System/Best" SETPOS 0
FILE "System/Best" READLINE best
'определение размеров экрана устройства и вычисление коэффициента предназначенного для оптимизации размеров изображений программы под различные экраны iPad,iPhone
maxx=SCREEN_WIDTH()
maxy=SCREEN_HEIGHT()
kof=maxy/768
kof1=maxx/1024
SHADOW OFFSET 2*.kof,2*.kof
'задание шрифта
DRAW FONT SIZE 40*.kof
DRAW FONT NAME "AmericanTypewriter-Light"
DRAW COLOR 0,0,.5
'ввод переменных
c=40*.kof
x(1)=c ! x(2)=maxx-c ! x(3)=c ! x(4)=maxx-c
y(1)=c ! y(2)=c ! y(3)=5*c ! y(4)=5*c

'графика
kletka
SPRITE 0 BEGIN 8*c,20*.kof
GRAPHICS CLEAR 0,0,1
DRAW RECT 4*c,10*.kof SIZE 4*c,10*.kof
SPRITE END
SPRITE 0 ALPHA .8
SPRITE 0 AT 3*c,4*c ANGLE 45
SPRITE 0 STAMP
SPRITE 0 AT 3*c,8.9*c ANGLE 45
SPRITE 0 STAMP
SPRITE 0 AT maxx-3*c,4*c ANGLE 135
SPRITE 0 STAMP
SPRITE 0 AT maxx-3*c,8.9*c ANGLE 135
SPRITE 0 STAMP
DRAW LINE 0,maxy-100*.kof TO maxx,maxy-100*.kof
DRAW LINE 0,maxy-200*.kof TO maxx,maxy-200*.kof
DRAW LINE maxx/2,maxy-200*.kof TO maxx/2,maxy
DRAW TEXT "ЛЕВО-ВЕРХ" AT .maxx/4,.maxy-150*.kof
DRAW TEXT "ЛЕВО-НИЗ" AT .maxx/4,.maxy-50*.kof
DRAW TEXT "ПРАВО-ВЕРХ" AT .maxx-.maxx/4,.maxy-150*.kof
DRAW TEXT "ПРАВО-НИЗ" AT .maxx-.maxx/4,.maxy-50*.kof
DRAW FONT SIZE 30*.kof
DRAW TEXT "Попытки:" AT .maxx/2,30*.kof
DRAW COLOR 1,0,0
DRAW TEXT "Лучший результат:" AT .maxx/2,180*.kof
DRAW COLOR 0,0,.5
FOR i=1 TO 3
DRAW CIRCLE maxx/2-200*.kof+100*.kof*i,100*.kof SIZE 25*.kof,40*.kof
NEXT i
REFRESH
SPRITE 0 DELETE
FILL COLOR .95,.8,.7


'создаем и размещаем на экране скрытые спрайты
FOR i=1 TO 24
SPRITE i BEGIN c*2,c*2
FILL CIRCLE c,c SIZE c,c*.6
DRAW CIRCLE c,c SIZE c,c*.6
SPRITE END
ang+=15
k+=1
IF k%3=0 THEN dob+=c
IF k=1 THEN ! x(1)+=c ! SPRITE i AT x(1)-c/2,y(1)+dob ANGLE ang ! ENDIF
IF k=2 THEN ! x(2)-=c ! SPRITE i AT x(2)+c/2,y(2)+dob ANGLE -ang ! ENDIF
IF k=3 THEN ! x(3)+=c ! SPRITE i AT x(3)-c/2,y(3)+dob ANGLE ang ! ENDIF
IF k=4 THEN ! x(4)-=c ! SPRITE i AT x(4)+c/2,y(4)+dob ANGLE -ang ! ENDIF
IF k=4 THEN k=0
NEXT i
'спрайт лучший результат
DRAW COLOR 1,0,0
SPRITE "best" BEGIN c*2,c
DRAW TEXT best AT c,c/2
SPRITE END
SPRITE "best" SHOW
SPRITE "best" AT .maxx/2,230*.kof
DRAW COLOR 0,0,.5
'спрайт корзинка
DRAW COLOR 0,0,.5
SPRITE "kor" BEGIN 160*.kof,80*.kof
FILL COLOR 1,1,0
FILL CIRCLE 80*.kof,0 SIZE 80*.kof
DRAW CIRCLE 80*.kof,0 SIZE 80*.kof
DRAW LINE 0,0 TO 160*.kof,0
SPRITE END
SPRITE "kor" AT .maxx/2,.maxy/2
SPRITE "kor" SHOW
'спрайт кнопка
SPRITE "knop" BEGIN .maxx/2,100*.kof
FILL COLOR 0,0,0
FILL RECT .maxx/4,50*.kof SIZE .maxx/4,50*.kof
SPRITE END
SPRITE "knop" AT -500,-500
SPRITE "knop" ALPHA .1
SPRITE "knop" SHOW


'установки уровня игры-их необходимо регулировать в главном цикле в зависимости от задач игры
ur=5 'частота появления яиц. с каждым уровнем надо уменьшать на 1.
t=1 ' определяет скорость движения яиц-постепенно должна уменьшаться.

tim=TIME()
PAGE 1 SHOW

' главный цикл
LOOP:
' считываем касание кнопок экрана
GET TOUCH 0 AS xx,yy
IF xx<=maxx/2 AND xx>-1 AND yy>maxy-100*.kof THEN kor=23
IF xx<=maxx/2 AND xx>-1 AND yy<maxy-100*.kof AND yy>maxy-200*.kof THEN kor=21
IF xx>maxx/2 AND yy>maxy-100*.kof THEN kor=24
IF xx>maxx/2 AND yy<maxy-100*.kof AND yy>maxy-200*.kof THEN kor=22
IF xx>-1 THEN
IF kor=21 THEN SPRITE "knop" AT .maxx/4,.maxy-150*.kof
IF kor=23 THEN SPRITE "knop" AT .maxx/4,.maxy-50*.kof
IF kor=22 THEN SPRITE "knop" AT .maxx-.maxx/4,.maxy-150*.kof
IF kor=24 THEN SPRITE "knop" AT .maxx-.maxx/4,.maxy-50*.kof
ELSE
SPRITE "knop" AT -500,-500
ENDIF
'устанавливаем корзинку в нужное место
IF kor=21 THEN SPRITE "kor" AT maxx/2-7*c, c*7
IF kor=23 THEN SPRITE "kor" AT maxx/2-7*c, c*12
IF kor=22 THEN SPRITE "kor" AT maxx/2+7*c, c*7
IF kor=24 THEN SPRITE "kor" AT maxx/2+7*c, c*12
'по истечении заданного времени (время определяющее скорость яиц) производим подсветку нужного яйца
IF TIME()>tim+t THEN
katS
'сравниваем последнее на дощечке яйцо с переменной касания кнопки.
FOR i=21 TO 24
i$=i
IF SPRITE_VISIBLE (i$)=1 THEN
IF kor=i THEN
'совпадение
korS
n+=1
t-=.005 ' изменение установочного параметра скорости
IF n=5 THEN ur-=1 ' изменение уровня появления нового яйца
IF n%20=0 AND ur>2 THEN ur-=1
'пишем на корзинке количество собранных яиц
SPRITE "kor" BEGIN
FILL COLOR 1,1,0
FILL CIRCLE 80*.kof,0 SIZE 80*.kof
DRAW CIRCLE 80*.kof,0 SIZE 80*.kof
DRAW LINE 0,0 TO 160*.kof,0
DRAW TEXT n AT 80*.kof,40*.kof
SPRITE END
'по необходимости обновляем надпись с лучшим результатом
IF n>best THEN
best+=1
SPRITE "best" BEGIN
GRAPHICS CLEAR
DRAW COLOR 1,0,0
DRAW TEXT n AT c,c/2
DRAW COLOR 0,0,.5
SPRITE END
ENDIF
ELSE
'ошибка-яйцо разбилось
nn+=1
FOR ii=1 TO 10
IF ii%2=0 THEN PAGE 2 HIDE ELSE PAGE 2 SHOW
piskS
PAUSE .1
NEXT ii
FILL COLOR 1,0,0
FILL CIRCLE maxx/2-200*.kof+100*.kof*nn,100*.kof SIZE 25*.kof,40*.kof
REFRESH
'конец игры
IF nn=3 THEN
kletka
PAGE 1 HIDE
DRAW FONT SIZE 60*.kof
DRAW TEXT "КОНЕЦ ИГРЫ" AT .maxx/2,.maxy/2-100*.kof
DRAW FONT SIZE 40*.kof
DRAW TEXT "Собранные ЯЙЦА: "&n AT .maxx/2,.maxy/2
DRAW RECT .maxx/2,.maxy/2+200 SIZE 100*.kof,50*.kof
DRAW TEXT "OK" AT .maxx/2,.maxy/2+200
FILE "System/Best" TRIM 0
FILE "System/Best" PRINT best
DRAW COLOR 1,0,0
DRAW TEXT "Лучший результат: "&best AT .maxx/2,.maxy/2+50*.kof
REFRESH

PAUSE 1
nazh
loo:
GET TOUCH 0 AS xx,yy
IF xx>-1 THEN RUN "Яйца.txt" ' начало новой игры
GOTO loo
ENDIF
ENDIF
SPRITE i HIDE
ENDIF
NEXT i
'мигание экрана(появление красной пустой страницы
FOR i=20 TO 1 STEP -1
i$=i
IF SPRITE_VISIBLE (i$)=1 THEN ! SPRITE i HIDE ! SPRITE i+4 SHOW ! GET SPRITE i+4 POS x1,y1 ! ENDIF
NEXT i
tim=TIME()
'появление нового яйца на случайной дощечке
IF k%ur=0 THEN
sl=RND(4)+1
SPRITE sl SHOW
ENDIF
k+=1
ENDIF
GOTO LOOP

REM ЛИСТ БУМАГИ В КЛЕТКУ
DEF kletka
SHADOW ON
ord=25
GRAPHICS CLEAR .99,.99,1
x=CEIL(.maxx/ord)
y=CEIL(.maxy/ord)
DRAW ALPHA .1
FOR i=1 TO x
IF i=x-5 THEN
DRAW ALPHA .3
DRAW SIZE 3*.kof
DRAW COLOR .8,0,0
ELSE
DRAW ALPHA .1
DRAW SIZE 1*.kof
DRAW COLOR 0,0,.5
ENDIF
DRAW LINE i*ord,0 TO ord*i,.maxy
NEXT i
FOR i1=1 TO y
DRAW LINE 0,ord*i1 TO .maxx,ord*i1
NEXT i1
DRAW ALPHA 1
SHADOW OFF
END DEF

'функция касания
DEF nazh
LOOP:
IF NOT x>-1 THEN LOOP
END DEF

'звук попадания яйца в корзину
DEF korS
NOTES MIDI 0,12,115
k=40+.i
NOTES MIDI 0,9,k,127
END DEF

'звук движения яйца
DEF katS
NOTES MIDI 1,12,120
NOTES MIDI 1,9,61,127
END DEF

'звук ошибки
DEF piskS
k=RND(7)+60
NOTES MIDI 2,12,123
NOTES MIDI 2,9,k,127
END DEF[/code]

Tantrixx
Posts: 119
Joined: Sun Nov 22, 2015 11:24 am
My devices: iPhone 5

Re: Игра ЯЙЦА

Post by Tantrixx » Thu Dec 24, 2015 5:15 am

Фант, подскажи пожалуйста, не могу сделать, чтоб случайным образом одно яйцо из четырёх появлялось и катилось. Потом нужно будет, чтоб дошло до 4 яиц и пока в картину не попадут, новое яйцо не появится.

Code: Select all

GRAPHICS
GRAPHICS CLEAR 1,1,1
OPTION ANGLE DEGREES
OPTION SPRITE POS CENTRAL
OPTION IMAGE POS CENTRAL
OPTION TEXT POS CENTRAL
SET ORIENTATION LANDSCAPE
SET TOOLBAR OFF
RANDOMIZE
maxx=SCREEN_WIDTH()
maxy=SCREEN_HEIGHT()
DRAW ALPHA 0.8
DRAW IMAGE "System/grass.png" AT maxx/2,maxy/2 SCALE 1.5

d$="das"
BUTTON d$ TEXT "выход" AT 3/2*(maxx/23),(maxy-2*(maxx/23)) SIZE (maxx/23)*3,(maxx/23)*2

'данные игры
tim=TIME()
t=1 ! ur=5
s=0.4 ! smv=.7 ! smn=.55
lv$="perch"
pnx=350 ! pnx= 220
pvx=350 ! pvy=122
lnx=103 ! lny=179
lvx=103 ! lvy=118 ! se=0.12 ! sbe=0.03
x1=103 ! x2=118
xe1=.2 ! ye1=.12
b=0 ! n=1.5
sch$=0 ! sche$=" Счет: "
' размер экрана 568,320


'размещение кур

SPRITE "hen_pv" LOAD "System/hen3.png"
SPRITE "hen_pv" AT 500,92 SCALE s
SPRITE "hen_pv" COPY "hen_lv"
SPRITE "hen_lv" AT 70,92 SCALE s FLIP 1
SPRITE "hen_pv" COPY "hen_ln"
SPRITE "hen_ln" AT 70,152 SCALE s FLIP 1
SPRITE "hen_pv" COPY "hen_pn"
SPRITE "hen_pn" AT 500,152 SCALE s 

SPRITE "hen_pv" SHOW
SPRITE "hen_lv" SHOW
SPRITE "hen_ln" SHOW
SPRITE "hen_pn" SHOW

'рисование насеста

DRAW COLOR 0,0,0
SPRITE lv$ BEGIN 50,10
DRAW SIZE 10
DRAW LINE 0,0 TO 45,0
SPRITE END
SPRITE lv$ AT 70,125
SPRITE lv$ COPY "perch_pv"
SPRITE "perch_pv" AT 505,125
SPRITE lv$ COPY "perch_pn"
SPRITE "perch_pn" AT 505,185
SPRITE lv$ COPY "perch_ln"
SPRITE "perch_ln" AT 70,185
SPRITE lv$ COPY "perch_lvu"
SPRITE "perch_lvu" RESIZE 100,10
SPRITE "perch_lvu" AT 130,149 ANGLE 30
SPRITE "perch_lvu" COPY "perch_lnu"
SPRITE "perch_lnu" AT 130,209 ANGLE 30
SPRITE "perch_lvu" COPY "perch_pvu"
SPRITE "perch_pvu" AT 449,144 ANGLE -30
SPRITE "perch_lvu" COPY "perch_pnu"
SPRITE "perch_pnu" AT 449,204 ANGLE -30

SPRITE "perch_pnu" SHOW
SPRITE "perch_pvu" SHOW
SPRITE "perch_lnu" SHOW
SPRITE "perch_lvu" SHOW
SPRITE "perch_ln" SHOW
SPRITE "perch_pn" SHOW
SPRITE "perch_pv" SHOW
SPRITE lv$ SHOW

SPRITE "b_egg" LOAD "System/broken egg.png"
SPRITE "b_egg" AT 175,280 SCALE sbe
SPRITE "b_egg" SHOW
SPRITE "b_egg" ALPHA 0

SPRITE "b_egg" COPY "dead_lives"
SPRITE "dead_lives" AT 350,60 SCALE sbe
SPRITE "dead_lives" SHOW
SPRITE "dead_lives" ALPHA 1
SPRITE "dead_lives" HIDE

SPRITE "masha_up_pv" LOAD "System/Masha up.png"
SPRITE "masha_up_pv" AT 340,220 SCALE smv FLIP 1
SPRITE "masha_up_pv" SHOW
SPRITE "masha_up_pv" COPY "masha_up_lv"
SPRITE "masha_up_lv" AT 230,220 SCALE smv

SPRITE "masha_ln" LOAD "System/Masha.png"
SPRITE "masha_ln" AT 230,205 SCALE smn ANGLE 10
SPRITE "masha_ln" COPY "masha_pn"
SPRITE "masha_pn" AT 340,205 SCALE smn ANGLE 10 FLIP 1

SPRITE "masha_pn" SHOW
SPRITE "masha_pn" HIDE
SPRITE "masha_ln" SHOW
SPRITE "masha_ln" HIDE
SPRITE "masha_up_lv" SHOW
SPRITE "masha_up_lv" HIDE

/*SPRITE "egg" LOAD "System/egg2.png"
SPRITE "egg" AT lvx,lvy SCALE se
SPRITE "egg" DELAY 0.01
SPRITE "egg" SHOW
SPRITE "egg" LOOP

SPRITE "egg" COPY "egg1"

SPRITE "egg1" AT lnx,lny SCALE se
SPRITE "egg1" DELAY .01
SPRITE "egg1" SHOW
SPRITE "egg1" HIDE*/

FOR i=1 TO 4
SPRITE i LOAD "System/egg2.png"
SPRITE i AT x1,x2 SCALE se
SPRITE i DELAY .01
SPRITE i SHOW
SPRITE i HIDE
NEXT i

LOOP:


DRAW TEXT sche$ AT 350,30
FIELD "schet" BACK ALPHA 0
FIELD "schet" TEXT sch AT 380,14



GET TOUCH 0 AS h,w
IF SPRITE_HIT ("hen_lv",h,w)=1 THEN

SPRITE "masha_up_pv" HIDE
SPRITE "masha_pn" HIDE
SPRITE "masha_ln" HIDE
SPRITE "masha_up_lv" SHOW
ENDIF

IF SPRITE_HIT ("hen_pv",h,w)=1 THEN

SPRITE "masha_up_lv" HIDE
SPRITE "masha_pn" HIDE
SPRITE "masha_ln" HIDE
SPRITE "masha_up_pv" SHOW
ENDIF

IF SPRITE_HIT ("hen_ln",h,w)=1 THEN

SPRITE "masha_up_pv" HIDE
SPRITE "masha_pn" HIDE
SPRITE "masha_up_lv" HIDE
SPRITE "masha_ln" SHOW
ENDIF

IF SPRITE_HIT ("hen_pn",h,w)=1 THEN

SPRITE "masha_up_pv" HIDE
SPRITE "masha_ln" HIDE
SPRITE "masha_up_lv" HIDE
SPRITE "masha_pn" SHOW
ENDIF

/*IF SPRITES_COLLIDE (i,"masha_up_lv")=1 THEN
SPRITE "egg" HIDE
SPRITE "egg1" LOOP
SPRITE "egg1" SHOW
sch=sch+1
ENDIF

IF SPRITES_COLLIDE (i,"masha_ln")=1 THEN
SPRITE "egg1" HIDE
SPRITE "egg1" STOP
sch=sch+1
ENDIF*/





IF TIME()>tim+t THEN
'katS это диф со звуком
'сравниваем последнее на дощечке яйцо с переменной касания кнопки. 
FOR i=1 TO 4
i$=i
IF SPRITE_VISIBLE (i$)=1 THEN 

IF masha_up_lv=i OR mascha_ln=i THEN 

'совпадение
'korS деф звук
sch+=1 
t-=.005 ' изменение установочного параметра скорости
IF sch=5 THEN ur-=1 ' изменение уровня появления нового яйца
IF sch%20=0 AND ur>2 THEN ur-=1
ENDIF
ENDIF
ENDIF
NEXT i
'случайный выбор жердочки

IF SPRITE_VISIBLE (i$)=0 THEN
ix=RND(4)+1

IF ix=1 THEN 

x1=103 ! x2=118
x=.2 ! y=.12

SPRITE ix AT x1,x2 SCALE se

SPRITE ix SHOW
SPRITE ix LOOP
SPRITE ix DA 5 DX x DY y

GET SPRITE ix POS x4,y4
ENDIF
IF ix=2 THEN 
x1=103 ! x2=179
x=.2 ! y=.12
ENDIF
IF ix=3 THEN 
x1=460 ! x2=118
ENDIF
IF ix=4 THEN
x1=460 ! x2=179
ENDIF

ENDIF




/*IF SPRITE_VISIBLE (i$)=1 THEN 
BREAK
ELSE
CONTINUE
endif */




/*SPRITE i DA 5 DX xe1 DY ye1

GET SPRITE i POS x2,y2*/

IF x1 >= 175  THEN 
x=0 ! y=1.5
ENDIF

IF x2 >=175 THEN 
 xe1=0 ! ye1=1.5
ENDIF

/*IF SPRITES_COLLIDE (i,"b_egg")=1 THEN 
SPRITE i HIDE
SPRITE "b_egg" ALPHA 1
SPRITE "dead_lives" SHOW
ENDIF

IF SPRITES_COLLIDE (i,"b_egg")=1 THEN 
SPRITE i HIDE
SPRITE "b_egg" ALPHA 1
SPRITE "dead_lives" SHOW
ENDIF*/

IF  BUTTON_PRESSED (d$)  THEN
SET TOOLBAR ON
ENDIF

GOTO LOOP

User avatar
Фант
Posts: 1363
Joined: Sat Nov 30, 2013 10:01 am
My devices: iPad 4 (iOS 9.3), iMac (MAC OS 11.03)
Location: Россия,Санкт-Петербург
Flag: Russia
Contact:

Re: Игра ЯЙЦА

Post by Фант » Thu Dec 24, 2015 5:47 am

Программа вообще не работает.
На айпаде выглядит вот так
Attachments
image.png
image.png (3.61 MiB) Viewed 3267 times

Tantrixx
Posts: 119
Joined: Sun Nov 22, 2015 11:24 am
My devices: iPhone 5

Re: Игра ЯЙЦА

Post by Tantrixx » Thu Dec 24, 2015 8:52 am

Я ещё не умею адаптировать под разные девайсы. :( Но попробую, и ещё раз :) одним словом у меня уже вроде и яйца появляются случайно, но не катятся, а треснутся на месте. Я пока что только одну левую жердь с яйцом оставил, но так и не разобрался. А под другой девайс размеры делать, это как? То есть я знаю как размеры взять с помощью какой команды. Как потом соотносить, на что делить? Или все с помощью проб и ошибок? :)))

User avatar
Фант
Posts: 1363
Joined: Sat Nov 30, 2013 10:01 am
My devices: iPad 4 (iOS 9.3), iMac (MAC OS 11.03)
Location: Россия,Санкт-Петербург
Flag: Russia
Contact:

Re: Игра ЯЙЦА

Post by Фант » Fri Dec 25, 2015 12:02 am

Tantrixx wrote:Я ещё не умею адаптировать под разные девайсы. :( Но попробую, и ещё раз :) одним словом у меня уже вроде и яйца появляются случайно, но не катятся, а треснутся на месте. Я пока что только одну левую жердь с яйцом оставил, но так и не разобрался. А под другой девайс размеры делать, это как? То есть я знаю как размеры взять с помощью какой команды. Как потом соотносить, на что делить? Или все с помощью проб и ошибок? :)))
Я под девайсы адаптирую следующим образом: беру высоту экрана девайса и делю на известную высоту(в ландшафтном расположении) айпада: у него 768 точек без верхнего тулбара. Это у меня коэффициент kof-пересчета размеров экрана. Вот этот коэффициент у меня расчитывается в самом начале программы и применяется ко всем числовым значениям в программе. Может можно делать както по другому, но я делаю так.
Можете посмотреть на примере программы ЯЙЦА. Конечно если у Вас нет айпада а только айфон-это трудно проверить не видя конечного результата.
А что у Вас с яцами не так? Сделайте их покруглее-может так катиться будут лучше :lol:

Tantrixx
Posts: 119
Joined: Sun Nov 22, 2015 11:24 am
My devices: iPhone 5

Re: Игра ЯЙЦА

Post by Tantrixx » Fri Dec 25, 2015 1:46 pm

Ура, покатились со всех жёрдочек поочереди. Доделаю с жизнями и выложу пока что без звука. Потом под айпад попробую сделать. И звуки какие нибудь добавлю. 8-)

User avatar
Фант
Posts: 1363
Joined: Sat Nov 30, 2013 10:01 am
My devices: iPad 4 (iOS 9.3), iMac (MAC OS 11.03)
Location: Россия,Санкт-Петербург
Flag: Russia
Contact:

Re: Игра ЯЙЦА

Post by Фант » Fri Dec 25, 2015 2:06 pm

Tantrixx wrote:Ура, покатились со всех жёрдочек поочереди. Доделаю с жизнями и выложу пока что без звука. Потом под айпад попробую сделать. И звуки какие нибудь добавлю. 8-)
Заценим! :D

Tantrixx
Posts: 119
Joined: Sun Nov 22, 2015 11:24 am
My devices: iPhone 5

Re: Игра ЯЙЦА

Post by Tantrixx » Sat Dec 26, 2015 1:47 pm

Фант, для айфона у меня игра готова. Есть одна проблема, не могу скорость адекватно увеличить. Она с первого цикла до максимума подымается.
Speed =0.01
Начиная от сюда это все находится в цикле.
Sprite i$ delay speed
...
...
IF sch%5=0 THEN
speed-=0.001
ENDIF

Sch это счёт. Для проверки хотел, чтоб после каждых 5 очков увеличивалась, а по факту хочу после каждого 10 или 15 очков чтоб увеличивалась скорость. Но у меня сразу до максимума :(

User avatar
Фант
Posts: 1363
Joined: Sat Nov 30, 2013 10:01 am
My devices: iPad 4 (iOS 9.3), iMac (MAC OS 11.03)
Location: Россия,Санкт-Петербург
Flag: Russia
Contact:

Re: Игра ЯЙЦА

Post by Фант » Sat Dec 26, 2015 1:53 pm

Tantrixx wrote:Фант, для айфона у меня игра готова. Есть одна проблема, не могу скорость адекватно увеличить. Она с первого цикла до максимума подымается.
Speed =0.01
Начиная от сюда это все находится в цикле.
Sprite i$ delay speed
...
...
IF sch%5=0 THEN
speed-=0.001
ENDIF

Sch это счёт. Для проверки хотел, чтоб после каждых 5 очков увеличивалась, а по факту хочу после каждого 10 или 15 очков чтоб увеличивалась скорость. Но у меня сразу до максимума :(
Правильно!
Если sch=0 данное условие тоже работает. 0 разделить на 5-делится тоже без остатка

Tantrixx
Posts: 119
Joined: Sun Nov 22, 2015 11:24 am
My devices: iPhone 5

Re: Игра ЯЙЦА

Post by Tantrixx » Sat Dec 26, 2015 2:35 pm

После счёта 5 speed =-0.196 :o

Post Reply